davewood

Handling long-running or heavy tasks inside a a requests is something you should avoid.

• It blocks the available processes for other requests.
• browser request timeout
• ...

Instead of using one of the job queue implementations available for perl

• Resque
• ActiveMQ
• ZeroMQ
• Gearman
• TheSchwartz
• ...

i decided to reuse/abuse my database.

Add a 'job' table

CREATE TABLE "job" (
  "id" serial NOT NULL,
  "test_id" integer NOT NULL,
  "status" character varying DEFAULT 'pending' NOT NULL,
  "created" timestamp NOT NULL,
  "data" character varying,
  PRIMARY KEY ("id")
);

Schedule a job

In our Catalyst Application users create and run tests. Running a test can take minutes to complete. So when the user clicks on the "run" button only a single insert is executed and the request returns.

INSERT INTO "job" ( "created", "test_id", "type")
VALUES ( '2013-09-17 09:53:54+0000', '220', 'test_foo');

Users can see job status

The next thing the user sees is a list of jobs and their status which can be any of the values "pending", "in_progress" or "finished".

Job Daemon

A daemon process takes care ofprocessing the jobs. I am using the excellent module Daemon::Control. script/epplication_job_daemon.initd

#!/usr/bin/env perl

use warnings;
use strict;
use Daemon::Control;
use FindBin qw/$Bin/;

# 1) configure user, group and perl path
my $user  = 'www-data';
my $group = 'www-data';
my $perl  = '/usr/bin/perl';

my $root     = $Bin;
my $program  = "$perl $root/myapp_job_daemon.pl";
my $name     = 'MyAppJobDaemon';
my $pid_file = $root . '/myapp_job_daemon.pid';

Daemon::Control->new(
    {
        name      => $name,
        lsb_start => '$all',
        lsb_stop  => '$all',
        lsb_sdesc => $name,
        lsb_desc  => $name,
        path      => $root . '/myapp_job_daemon.initd',

        user      => $user,
        group     => $group,
        directory => $root,
        program   => $program,

        pid_file    => $pid_file,
        stderr_file => $root . '/myapp_job_daemon.out',
        stdout_file => $root . '/myapp_job_daemon.out',

        fork => 2,    # Default: 2
    }
)->run;

1. create initd file ... ./script/myapp_job_daemon.initd get_init_file > foo
2. copy to /etc/init.d/myapp_job_daemon ... cp foo /etc/init.d/myapp_job_daemon
3. install to runlevels ... update-rc.d myapp_job_daemon defaults

script/myapp_job_daemon.pl

the code for job processing

#!/usr/bin/env perl

use strict;
use warnings;
use 5.010;
use FindBin qw/$Bin/;
use lib "$Bin/../lib";
use MyApp::Util;

my $verbose  = 1;
my $interval = 5;
my $schema   = MyApp::Util::get_schema();
run();

sub run {
    while (1) {
        my $job = check_queue();
        if ( $job ) {
            process_job( $job );
        }
        else {
            sleep($interval);
        }
    }
}

sub check_queue {
    my $schema = shift;
    return $schema->resultset('Job')->search( { status => 'pending' } )->first;
}

sub process_job {
    my $job = shift;

    say "Processing job: " . $job->id
        if $verbose;

    my $test = $job->test;
    die "no test found.\n" unless $test;

    say "Processing test: " . $test->name . '(' . $test->id . ')'
        if $verbose;

    my $test_env = MyApp::Util::get_test_env( $schema );

    $job->update( { status => 'in_progress' } );

    my @results = $test->run( $test_env );

    $job->update(
        {
            data   => \@results,
            status => 'finished',
        }
    );

    say "Finished processing " . @results . " steps."
        if $verbose;
}

Disadvantages

• client polls results every n seconds
• daemon polls database for pending jobs (could use DB triggers)
• doesnt scale so well

But it works and I can come up with a better solution if required.